Galleria Membri ? - Ernia e Laparocele

Sub DisplayRecentlySeen(intNrOfPeople,strRecentlyMode)
	Dim rsRecently, intRecentlyCount, intMinDiff, intHrsDiff,IntDayDiff
	If Not isNumeric(intNrOfPeople) or intNrOfPeople < 1 Then
		intNrOfPeople = 10
	End If
	If trim(strRecentlyMode) <> "simple" and trim(strRecentlyMode) <> "extended" Then
		strRecentlyMode = "simple"
	End If
	Call DoHideCategory("RecentlySeen")
	HideForumCat = strUniqueID & "HideCatRecentlySeen"
	If Request.Cookies(HideForumCat) <> "Y" Then
		strSql = "SELECT MEMBER_ID, M_NAME, M_LASTHEREDATE FROM " & strMemberTablePrefix & "MEMBERS WHERE M_NAME <> 'n/a' AND M_STATUS = 1 ORDER BY M_LASTHEREDATE DESC"
		Set rsRecently = my_conn.Execute(TopSQL(strsql,intNrOfPeople))	
		Response.Write  "              <tr>" & vbNewLine & _
				"                <td bgcolor=""" & strCategoryCellColor & """ colspan=""" & sGetColspan(7,6) & """><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """ color=""" & strCategoryFontColor & """><a href=""" & ScriptName & "?" & HideForumCat & "=Y"">" & getCurrentIcon(strIconMinus,"Collapse This Category","") & "</a> <b>Recently Seen Members</b></font></td>" & vbNewLine & _
				"              </tr>" & vbNewLine & _
				"              <tr bgcolor=""" & strForumCellColor & """>" & vbNewLine & _
				"                <td align=""left""> </td>" & vbNewline & _
				"                <td colspan=""" & sGetColspan(6,5) & """>" & vbNewLine & _
				"                <font face=""" & strDefaultFontFace & """ size=""" & strFooterFontSize & """ color=""" & strForumFontColor & """>" & vbNewLine 
		intRecentlyCount = 1
		Do While NOT rsRecently.EOF
			If intRecentlyCount > 1 Then
			        Response.Write ", "
			End If
			Response.Write profileLink(rsRecently("M_NAME"), rsRecently("MEMBER_ID")) & " "
			intMinDiff = datediff("n",strToDate(rsRecently("M_LASTHEREDATE")),strForumTimeAdjust)
			intHrsDiff = int(intMinDiff/60)
			intDayDiff = int(intHrsDiff / 24)
			intMinDiff = intMinDiff mod 60
			intHrsDiff = intHrsDiff mod 24
			Select Case strRecentlyMode
			Case "extended"
				If intDayDiff = 1 Then 
					Response.Write intDayDiff & " day, "
				End If
				If intDayDiff > 1 Then 
					Response.Write intDayDiff & " days, "
				End If			
				If intHrsDiff = 1 Then 
					Response.Write intHrsDiff & " hour, "
				End If
				If intHrsDiff > 1 Then 
					Response.Write intHrsDiff & " hours, "
				End If
				If intMinDiff > 1 Then
					Response.Write intMinDiff & " minutes ago"
				Else
					Response.Write " 1 minute ago"
				End If
			Case "simple"
				Response.Write "("
				If intDayDiff > 0 Then
					If intDayDiff = 1 Then 
						Response.Write intDayDiff & " day "
					Else
						Response.Write intDayDiff & " days "
					End If			
				Elseif intHrsDiff > 0 Then
					If intHrsDiff = 1 Then 
						Response.Write intHrsDiff & " hour "
					Else
						Response.Write intHrsDiff & " hours "
					End If
			        Else
					If intMinDiff > 1 Then
						Response.Write intMinDiff & " minutes "
					Else
						Response.Write "1 minute "
					End If
				End If
				Response.Write "ago"
				Response.Write  ")"
			End Select
			rsRecently.MoveNext
			intRecentlyCount = intRecentlyCount + 1
		Loop
		rsRecently.Close
		Set rsRecently = Nothing
		Response.Write "."
		Response.Write  "                 </font>" & vbNewLine & _
				"	          </td>" & vbNewLine & _
				"		</tr>" & vbNewLine
	Else
		Response.Write  "              <tr>" & vbNewLine & _
				"                <td bgcolor=""" & strCategoryCellColor & """colspan=""" & sGetColspan(7,6) & """><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """ color=""" & strCategoryFontColor & """><a href=""" & ScriptName & "?" & HideForumCat & "=N"">" & getCurrentIcon(strIconPlus,"Expand This Category","") & "</a> <b>Recently Seen Members</b></font></td>" & vbNewLine & _
				"              </tr>" & vbNewLine 
	End If
End Sub
%>